# Luke's config for the Zoomer Shell

# Enable colors and change prompt:
autoload -U colors && colors

export GIT_PS1_SHOWUPSTREAM="verbose"

function sshi() {
  if [[ -n $SSH_CLIENT || -n $SSH_TTY ]]; then
    echo "%{$fg[cyan]%}@%m%f "
  fi
}

#PS1="%B%{$fg[yellow]%}%n  %{$fg[blue]%}%~ %{$fg[green]%}$%{$reset_color%}%b "
PS1="%B%{$fg[yellow]%}%n$(sshi) %{$fg[blue]%}%~ %{$fg[green]%}v%{$reset_color%}%b "
#PS1="%B%{$fg[red]%}[%{$fg[yellow]%}%n%{$fg[green]%}@%{$fg[blue]%}%M %{$fg[magenta]%}%~%{$fg[red]%}]%{$reset_color%}$%b "  # Luke Conf

source /usr/lib/git-core/git-sh-prompt

set_git_prompt() {
	RPS1="%{$fg[yellow]%} $(__git_ps1 " %s") %{$reset_color%} "
}

# Add the function to the precmd hook list
autoload -Uz add-zsh-hook
add-zsh-hook precmd set_git_prompt


zstyle ':completion:*' matcher-list 'm:{a-z}={A-Za-z}'
zstyle ':completion:*' list-colors "${(s.:.)LS_COLORS}"

# History in cache directory:
HISTSIZE=100000
SAVEHIST=100000
HISTFILE=~/.cache/zsh/history
setopt appendhistory
setopt sharehistory
setopt hist_ignore_space
setopt INTERACTIVE_COMMENTS

# Basic auto/tab complete:
autoload -U compinit
zstyle ':completion:*' menu select
zmodload zsh/complist
compinit
_comp_options+=(globdots)		# Include hidden files.

# vi mode
bindkey -v
export KEYTIMEOUT=1
bindkey '^R' history-incremental-search-backward

# Use vim keys in tab complete menu:
bindkey -M menuselect 'h' vi-backward-char
bindkey -M menuselect 'k' vi-up-line-or-history
bindkey -M menuselect 'l' vi-forward-char
bindkey -M menuselect 'j' vi-down-line-or-history
bindkey -v '^?' backward-delete-char

# Change <> for vi mode
function zle-line-init zle-keymap-select {
	if [[ ${KEYMAP} == vicmd ]] ||
       [[ $1 = 'block' ]]; then
		#PS1="%B%{$fg[yellow]%}%n%  %{$fg[blue]%}%~ %{$fg[green]%}<%{$reset_color%}%b "
		PS1="%B%{$fg[yellow]%}%n$(sshi) %{$fg[blue]%}%~ %{$fg[green]%}<%{$reset_color%}%b "
	elif [[ ${KEYMAP} == main ]] ||
		[[ ${KEYMAP} == viins ]] ||
		[[ ${KEYMAP} = '' ]] ||
		[[ $1 = 'beam' ]]; then
		PS1="%B%{$fg[yellow]%}%n$(sshi) %{$fg[blue]%}%~ %{$fg[green]%}>%{$reset_color%}%b "
	else
		PS1="%B%{$fg[yellow]%}%n$(sshi) %{$fg[blue]%}%~ %{$fg[green]%}v%{$reset_color%}%b "
	fi
    zle reset-prompt
}

zle -N zle-line-init
zle -N zle-keymap-select

# Use lf to switch directories and bind it to ctrl-o
lfcd () {
    tmp="$(mktemp)"
    lf -last-dir-path="$tmp" "$@"
    if [ -f "$tmp" ]; then
        dir="$(cat "$tmp")"
        rm -f "$tmp"
        [ -d "$dir" ] && [ "$dir" != "$(pwd)" ] && cd "$dir"
    fi
}
bindkey -s '^o' 'lfcd\n'

# Edit line in vim with ctrl-e:
autoload edit-command-line; zle -N edit-command-line
bindkey '^e' edit-command-line

# Load aliases and shortcuts if existent.
[ -f "$HOME/.config/shortcutrc" ] && source "$HOME/.config/shortcutrc"
[ -f "$HOME/.config/aliasrc" ] && source "$HOME/.config/aliasrc"

# Load zsh-syntax-highlighting; should be last.
source /usr/share/zsh-autosuggestions/zsh-autosuggestions.zsh 2>/dev/null
source /usr/share/zsh-syntax-highlighting/zsh-syntax-highlighting.zsh 2>/dev/null
# fpath=(~/.local/zsh-completions/src $fpath)

# Make zsh autocomplete with up arrow
source ~/.local/zsh/zsh-history-substring-search/zsh-history-substring-search.zsh
bindkey '^[[A' history-substring-search-up
bindkey '^[[B' history-substring-search-down